ASMB,A,B,L,T
*OPERATING PROCEOURE
*STARTING ADDRESS 100
*SWITCH REGISTER (BITS 0-5) SELECT CODE OF OUTPUT DEVICE
*SET BIT 15 TO A I TO LOOP
*OUTPUT DEVICE-BUF'D TTY CARD(MOST EFFECTIVE)OR GND TRUE I/O
*TTY CARD MUST HAVE HOOD REMOVED,GRD TRUE I/O MUST HAVE
*SPECIAL HOOD CONNECTOR (SAME AS DMA TEST)
*"RUN"
*HALT 08
*SET SWITCH REGISTER FOR LAST AVAILABLE WORD OF MEMORY
*"RUN"
*THIS PROGRAM MUST BE RELOADED TO RESTART.
      ORG 4B
      HLT 4B
      HLT 5B
      ORG 100B
      LDB WRD1     GET "JMP GO" INSTRUCTION.
      LIA 1        GET DEVICE SELECT CODE.
      ELA,ARS      PUT LOOPING FLAG IN E REG.
      STB 0,I      PUT "JMP GO" IN TRAP CELL.
      IOR S1       CONFIGURE
      STA S1        I/O
      IOR S2         INSTRUCTIONS.
      STA S2
      CLA,SEZ      LOOPING FLAG SET?
      STA END      YES.
      HLT 0
      LIA 1        GET MAXIMUM MEMORY
      STA MAXAD     ADDRESS AND SAVE IT.
      RSS
END   HLT 77B      DONE. "RUN" TO RESTART.
      STF 0        ENABLE INTERRUPTS.
      LDA OUT      CONFIGURE INTERFACE
S1    OTA 0         FOR OUTPUT.
      LDA BEGIN    STARTING ADDRESS FOR
R1    LDB INSTR     JUMP SELF INSTRUCTION.
R2    STB 0,I
      OTA 1
S2    OCT 1100     THIS BECOMES A STC CHAN,C.
      JMP 0,I      EXECUTE JUMP SELF.
GO    CPA MAXAD    END OF MEMORY?
      JMP END      YES.
      INA          BUMP MEMORY ADDRESS OF
      INB           JUMP SELF INSTRUCTION.
      CPB PAGE     END OF MEMORY PAGE?
      JMP R1       YES.
      JMP R2       NO.
WRD1  JMP GO
OUT   OCT 110000
BEGIN OCT 2000
INSTR OCT 26000
MAXAD OCT 0
PAGE  OCT 30000
      END